先ほどは「バッチ・ジョブに投入した場合は QPRTJOB」と説明したが
正確には IBM は

「現在のジョブのユーザー名が、現在実行されている
      ユーザー・プロファイルのものと 同じでない場合」

が QPRTJOB として実行されると説明しているがこの説明で理解できる人は
果たしてどれくらいいるのだろうか?

• SNDNETSPLF で送信して受信されて作成されたスプールは QPRTJOB
• RSTOBJ などで復元されて作成されるスプールは QPRTJOB
• QBATCH に投入されて実行して作成されたスプールは QPRTJOB

であることがわかっている。
そこでバッチ・ジョブに投入されて印刷スプールが QPRTJOB となってしまったときも
考慮したプログラムに書き換えると下記のようになる。

【 サンプルCLP : TESTPRT3 】

0001.00              PGM
0002.00 /*-------------------------------------------------------------------*/
0003.00 /*   TESTPRT3  :   印刷スプールをデータ・ベースへコピーする          */
0004.00 /*                                                                   */
0005.00 /*   2017/08/19  作成                                                */
0006.00 /*-------------------------------------------------------------------*/
0007.00              DCL        VAR(&JOB)  TYPE(*CHAR) LEN(10)
0008.00              DCL        VAR(&USER) TYPE(*CHAR) LEN(10)
0009.00              DCL        VAR(&JOBNBR) TYPE(*CHAR) LEN(6)
0010.00              DCL        VAR(&TYPE) TYPE(*CHAR) LEN(1)
0011.00              DCL        VAR(&RCVDTA) TYPE(*CHAR) LEN(128)
0012.00              DCL        VAR(&RCVLEN) TYPE(*CHAR) LEN(4)
0013.00              DCL        VAR(&APIERR) TYPE(*CHAR) LEN(116) +
0014.00                           VALUE(X'000074') /* 2 進数  */
0015.00
0016.00 /*( 環境の取得 )*/
0017.00              RTVJOBA    JOB(&JOB) USER(&USER) NBR(&JOBNBR) TYPE(&TYPE)
0018.00
0019.00 /*( データ・ベースの作成 )*/
0020.00              CRTPF      FILE(QTEMP/QPRINT) RCDLEN(132) IGCDTA(*YES) +
0021.00                           LVLCHK(*NO) AUT(*ALL)
0022.00              MONMSG     CPF7300
0023.00
0024.00 /*( スプールを *HOLD にオーバーライド )*/
0025.00              OVRPRTF    FILE(QPRTOBJD) HOLD(*YES) LVLCHK(*NO) +
0026.00                           SECURE(*YES) OVRSCOPE(*JOB) OPNSCOPE(*JOB)
0027.00
0028.00 /*( 印刷ジョブの実行 )*/
0029.00              DSPOBJD    OBJ(SPOOLWTR) OBJTYPE(*LIB) OUTPUT(*PRINT)
0030.00              DLTOVR     FILE(QPRTOBJD) LVL(*JOB)
0031.00
0032.00 /*( QPRTJOB の JOB 番号を検索 )*/
0033.00              IF         COND(&TYPE *EQ '0') THEN(DO) /*  バッチ  */
0034.00              CHGVAR     VAR(%BIN(&RCVLEN)) VALUE(128)
0035.00              CALL       PGM(QSPRILSP) PARM(&RCVDTA &RCVLEN +
0036.00                           'SPRL0100' &APIERR)
0037.00              CHGVAR     VAR(&JOB) VALUE(%SST(&RCVDTA 19 10))
0038.00              CHGVAR     VAR(&USER) VALUE(%SST(&RCVDTA 29 10))
0039.00              CHGVAR     VAR(&JOBNBR) VALUE(%SST(&RCVDTA 39 6))
0040.00              ENDDO      /*  バッチ  */
0041.00
0042.00 /*( 印刷スプールをデータ・ベースにコピー )*/
0043.00              CPYSPLF    FILE(QPRTOBJD) TOFILE(QTEMP/QPRINT) +
0044.00                           JOB(&JOBNBR/&USER/&JOB) SPLNBR(*LAST)
0045.00
0046.00 /*( 不要になったスプールを削除する )*/
0047.00              DLTSPLF    FILE(QPRTOBJD) JOB(*) SPLNBR(*LAST)
0048.00              ENDPGM

【解説】