PGM        PARM(&DTAQQLIB)                                         
/*-------------------------------------------------------------------*/         
/*   CHKDTAQCL   : *DTAQ のデータの検査                              */         
/*                                                                   */         
/*   2017/07/17  作成                                                */         
/*-------------------------------------------------------------------*/         
             DCL        VAR(&DTAQQLIB) TYPE(*CHAR) LEN(20)                      
             DCL        VAR(&DTAQ) TYPE(*CHAR) LEN(10)                          
             DCL        VAR(&DTAQLIB) TYPE(*CHAR) LEN(10)                       
             DCL        VAR(&MSG) TYPE(*CHAR) LEN(132)                          
             DCL        VAR(&MSGID) TYPE(*CHAR) LEN(7)                          
             DCL        VAR(&MSGF) TYPE(*CHAR) LEN(10)                          
             DCL        VAR(&MSGFLIB) TYPE(*CHAR) LEN(10)                       
             DCL        VAR(&MSGDTA) TYPE(*CHAR) LEN(132)                       
             DCL        VAR(&TYPE) TYPE(*CHAR) LEN(1)                           
             DCL        VAR(&TOPGMQ) TYPE(*CHAR) LEN(10)                        
             DCL        VAR(&MSGTYPE) TYPE(*CHAR) LEN(10) +                     
                          VALUE('*ESCAPE   ')                                   
             DCL        VAR(&APIERR) TYPE(*CHAR) LEN(116) +                     
                          VALUE(X'000074') /* 2 進数  */                        
             DCL        VAR(&NULL4) TYPE(*CHAR) LEN(4) +                        
                          VALUE(X'00000000')                                    
             DCL        VAR(&WAIT) TYPE(*DEC) LEN(5 0) VALUE(0)                 
             DCL        VAR(&MSGBUF) TYPE(*CHAR) LEN(4096)                      
             DCL        VAR(&MSGLEN) TYPE(*DEC) LEN(8 0)                        
             DCL        VAR(&KEYLEN) TYPE(*DEC) LEN(3 0)                        
             DCL        VAR(&SENDER) TYPE(*DEC) LEN(3 0)                        
             DCL        VAR(&DTA_REC) TYPE(*DEC) LEN(5 0)                       
             MONMSG     MSGID(CPF0000) EXEC(GOTO CMDLBL(ERROR))                 
                                                                                
/*( 環境の取得 )*/                                                              
             RTVJOBA    TYPE(&TYPE)                                             
             IF         COND(&TYPE *EQ '0') THEN(DO) /*  バッチ  */             
             CHGVAR     VAR(&TOPGMQ) VALUE('*SYSOPR   ')                        
             ENDDO      /*  バッチ  */                                          
             ELSE       CMD(DO) /*  対話式  */                                  
             CHGVAR     VAR(&TOPGMQ) VALUE('*TOPGMQ   ')                        
             ENDDO      /*  対話式  */                                          
                                                                                
/*( パラメータの読取り )*/                                                      
             CHGVAR     VAR(&DTAQ) VALUE(%SST(&DTAQQLIB 01 10))                 
             CHGVAR     VAR(&DTAQLIB) VALUE(%SST(&DTAQQLIB 11 10))              
                                                                                
/*( *DTAQ の読取り )*/                                                          
             CHGVAR     VAR(&WAIT) VALUE(0) /*  即時読取り  */                  
             CALL       PGM(QRCVDTAQ) PARM(&DTAQ &DTAQLIB &MSGLEN +             
                          &MSGBUF &WAIT '  ' &KEYLEN '' &SENDER '' +            
                          '*NO       ' &DTA_REC &APIERR)                        
             IF         COND(%SST(&APIERR 5 4) *NE &NULL4) THEN(DO)             
             SNDPGMMSG  +                                                       
                          MSG('API: QRCVDTAQ の実行で次のエラーが発生 +         
                           しました。 ') MSGTYPE(*DIAG)                         
             GOTO       APIERR                                                  
             ENDDO                                                              
             IF         COND(&MSGLEN > 0) THEN(RETURN)                          
             ELSE       CMD(DO)                                                 
             CHGVAR     VAR(&MSGDTA) +                                          
                          VALUE(' データ待ち行列にはデータはありませ +          
                           ん。 ')                                              
             GOTO       SNDMSG                                                  
             ENDDO                                                              
             RETURN                                                             
                                                                                
 APIERR:                                                                        
             CHGVAR     VAR(&MSGID) VALUE(%SST(&APIERR 9 7))                    
             CHGVAR     VAR(&MSGDTA) VALUE(%SST(&APIERR 17 100))                
             CHGVAR     VAR(&MSGF) VALUE('QCPFMSG   ')                          
             CHGVAR     VAR(&MSGFLIB) VALUE('QSYS      ')                       
             GOTO       SNDMSG                                                  
                                                                                
 ERROR:      RCVMSG     MSGTYPE(*LAST) RMV(*NO) MSG(&MSG) +                     
                          MSGDTA(&MSGDTA) MSGID(&MSGID) MSGF(&MSGF) +           
                          MSGFLIB(&MSGFLIB)                                     
 SNDMSG:     IF         COND(&MSGID *EQ ' ') THEN(DO)                           
             SNDPGMMSG  MSGID(CPF9897) MSGF(QCPFMSG) MSGDTA(&MSG) +             
                          TOMSGQ(&TOPGMQ) MSGTYPE(&MSGTYPE)                     
             ENDDO                                                              
             ELSE       CMD(DO)                                                 
             SNDPGMMSG  MSGID(&MSGID) MSGF(&MSGFLIB/&MSGF) +                    
                          MSGDTA(&MSGDTA) TOMSGQ(&TOPGMQ) +                     
                          MSGTYPE(&MSGTYPE)                                     
             ENDDO                                                              
             ENDPGM