A                                      DSPSIZ(27 132 *DS4)                 
     A  *DS4                                MSGLOC(27)                          
     A                                      PRINT                               
     A                                      HELP                                
     A                                      HLPSCHIDX(*LIBL/QHPW1)              
     A                                      ALTHELP(CA01)                       
     A                                      HLPTITLE(' データ入力画面 ')        
     A                                      HLPPNLGRP('DFU/DESL/GEN' QHDZDF1)   
     A                                      INDARA                              
     A          R DSPHEAD                   TEXT(' 初期画面レコード ')          
     A                                      CHANGE(01)                          
     A                                      CF03(03 ' 終了 ')                   
     A                                      CF05(05 ' 再表示 ')                 
     A                                      CF06(06 ' 様式の選択 ')             
     A                                      CF09(09 ' 挿入 ')                   
     A                                      CF10(10 ' 入力 ')                   
     A                                      CF11(11 ' 変更 ')                   
     A                                      ROLLUP(07 ' ROLLUP')                
     A                                      ROLLDOWN(08 'ROLLDWN')              
     A                                  1  2' 商品マスター登録 '                
     A*( 表示モード記述 )                                                       
     A                                  1 49' モード  . . :'                    
     A            DSPMOD        14A  O  1 66                                    
     A                                  2  2' 様式  . . . . :'                  
     A            RECORD        10A  O  2 21                                    
     A                                  2 49' ファイル  . :'                    
     A            FILE          10A  O  2 66                                    
     A*( フィールド記述 )                                                       
     A                                  4  2' 商品コード :'                     
     A            SHCODE        10A  B  4 16                                    
     A  43                                  DSPATR(RI)                          
     A                                      CHECK(FE)                           
     A                                 12 14' 必要な項目を入力して，実行キーを +
     A                                       押してください。 '                 
     A                                      COLOR(BLU)                          
     A*( 機能キーの記述 )                                                       
     A                                 22  2'F3= 終了 '                         
     A                                      COLOR(BLU)                          
     A                                 22 26'F5= 最新表示 '                     
     A                                      COLOR(BLU)                          
     A                                 22 51'F9= 挿入  '                        
     A                                      COLOR(BLU)                          
     A                                 22 72'F10= 入力 '                        
     A                                      COLOR(BLU)                          
     A                                 23  2'F11= 変更 '                        
     A                                      COLOR(BLU)                          
     A          R DSPDTA01                  TEXT(' 明細画面レコード 01')        
     A                                      CHANGE(01)                          
     A                                      CF03(03 ' 終了 ')                   
     A                                      CF05(05 ' 再表示 ')                 
     A                                      CF09(09 ' 挿入 ')                   
     A                                      CF10(10 ' 入力 ')                   
     A                                      CF11(11 ' 変更 ')                   
     A                                      CF12(12 ' 前画面 ')                 
     A                                      CF23(23 ' 削除 ')                   
     A                                      ROLLUP(07 ' ROLLUP')                
     A                                      ROLLDOWN(08 'ROLLDWN')              
     A                                      SETOF(99)                           
     A            ERRMSG       144A  P                                          
     A                                  1  2' 商品マスター登録 '                
     A*( 表示モード記述 )                                                       
     A                                  1 49' モード  . . :'                    
     A            DSPMOD        14A  O  1 66                                    
     A                                  2  2' 様式  . . . . :'                  
     A            RECORD        10A  O  2 21                                    
     A                                  2 49' ファイル  . :'                    
     A            FILE          10A  O  2 66                                    
     A*( フィールド記述 )                                                       
     A                                  4  2' 商品コード :'                     
     A            SHCODE        10A  B  4 16                                    
     A  43                                  DSPATR(RI)                          
     A                                      DSPATR(PR)                          
     A  32                                  DSPATR(UL)                          
     A                                      CHECK(FE)                           
     A                                  5  2' 商品名 :'                         
     A            SHNAME        24O  B  5 16                                    
     A  43                                  DSPATR(RI)                          
     A  30                                  DSPATR(PR)                          
     A N30                                  DSPATR(UL)                          
     A                                      CHECK(FE)                           
     A                                  6  2' 単価 :'                           
     A            SHTANK         7Y 0B  6 16                                    
     A  43                                  DSPATR(RI)                          
     A  30                                  DSPATR(PR)                          
     A N30                                  DSPATR(UL)                          
     A                                      EDTCDE(1)                           
     A                                      CHECK(RB)                           
     A                                  7  2' 品種コード :'                     
     A            SHSCOD         4A  B  7 16                                    
     A  43                                  DSPATR(RI)                          
     A  30                                  DSPATR(PR)                          
     A N30                                  DSPATR(UL)                          
     A                                      CHECK(FE)                           
     A  71                                  ERRMSGID(CPF9897 QSYS/QCPFMSG -     
     A                                      71 &ERRMSG)                         
     A            HNSNAM    R        O  7 21REFFLD(HINSHUR/HNSNAM QTRFIL/HINSHU)
     A*( 機能キーの記述 )                                                       
     A                                 22  2'F3= 終了 '                         
     A                                      COLOR(BLU)                          
     A                                 22 26'F5= 最新表示 '                     
     A                                      COLOR(BLU)                          
     A                                 22 51'F9= 挿入  '                        
     A                                      COLOR(BLU)                          
     A                                 22 72'F10= 入力 '                        
     A                                      COLOR(BLU)                          
     A                                 23  2'F11= 変更 '                        
     A                                      COLOR(BLU)                          
     A                                 23 26'F23= 削除 '                        
     A                                      COLOR(BLU)                          
     A                                 23 51'F12= 前画面 '                      
     A                                      COLOR(BLU)                          
     A          R ENDOPT                                                        
     A                                      TEXT(' 終了画面 ')                  
     A                                      CSRLOC(LIN        POS)              
     A                                  1 33' データ入力の終了 '                
     A                                      DSPATR(HI)                          
     A                                  3  4' 処理されたレコード数 '            
     A  30                                  DSPATR(ND)                          
     A                                  5  6' 追加  . . . . . :'                
     A  30                                  DSPATR(ND)                          
     A            ADDRCD         5Y 0O  5 35EDTCDE(1)                           
     A  30                                  DSPATR(ND)                          
     A                                  6  6' 変更  . . . . . :'                
     A  30                                  DSPATR(ND)                          
     A            CHGRCD         5Y 0O  6 35EDTCDE(1)                           
     A  30                                  DSPATR(ND)                          
     A                                  7  6' 削除  . . . . . :'                
     A  30                                  DSPATR(ND)                          
     A            DLTRCD         5Y 0O  7 35EDTCDE(1)                           
     A  30                                  DSPATR(ND)                          
     A                                 12  2' 選択項目を打鍵して，実行キーを押 +
     A                                       してください。 '                   
     A                                      COLOR(BLU)                          
     A                                 14  5' データ入力の終了  . . . . . .'    
     A            ANS            1A  B 14 39VALUES('Y' 'N')                     
     A                                 14 53'Y=YES, N=NO'                       
     A                                 23  2'F3= 終了 '                         
     A                                      COLOR(BLU)                          
     A                                 23 15'F12= 前画面 '                      
     A                                      COLOR(BLU)                          
     A            LIN            3S 0H                                          
     A            POS            3S 0H