     A                                      DSPSIZ(24 80 *DS3)                  
     A                                      MSGLOC(24)                          
     A                                      PRINT                               
     A          R SFREC01                   SFL                                 
     A                                      TEXT(' ＳＦＬ明細行 ')              
     A            GYO            4A  O  8  2TEXT(' № ')                        
     A            SHCODE        10A  O  8  7TEXT(' 商品コード ')                
     A            SHNAME        24O  O  8 20TEXT(' 商品名 ')                    
     A            SHTANK         7Y 0O  8 45TEXT(' 単価 ')                      
     A                                      EDTCDE(K)                           
     A            SHSCOD         4A  O  8 56TEXT(' 品種コード ')                
     A                                                                          
     A          R SFCTL01                   SFLCTL(SFREC01)                     
     A                                      TEXT(' ＳＦＬ制御見出 ')            
     A                                      OVERLAY                             
     A* SFLPAG : 1 画面での表示行数                                             
     A* SFLSIZ : サブファイル全体の容量                                         
     A                                      SFLSIZ(14)                          
     A                                      SFLPAG(13)                          
     A  41                                  SFLDSPCTL                           
     A  42                                  SFLDSP                              
     A  44                                  SFLCLR                              
     A                                      ROLLUP(14 ' 次頁 ')                 
     A                                      ROLLDOWN(15 ' 前頁 ')               
     A                                      CF03(03 ' 終了 ')                   
     A                                  1 27' 商品マスター照会 '                
     A                                      DSPATR(RI)                          
     A                                      COLOR(PNK)                          
     A*( 明細行の桁見出し )                                                     
     A                                  7  2' № '                              
     A                                      DSPATR(HI)                          
     A                                  7  7' 商品コード '                      
     A                                      DSPATR(HI)                          
     A                                  7 20' 商品名 '                          
     A                                      DSPATR(HI)                          
     A                                  7 45' 単価 '                            
     A                                      DSPATR(HI)                          
     A                                  7 56' 品種コード '                      
     A                                      DSPATR(HI)