H DFTNAME(ANS005) DATEDIT(*YMD/)                                                               
     F******** 商品コード照会 *****************************************                             
     FANS005FM  CF   E             WORKSTN                                                          
     FSHOHIN    IF   E           K DISK                                                             
     F*****************************************************************                             
    +ISHOHINR                                                                                       
     I              SHCODE                      NHCODE                                              
     D KYR             S             10    DIM(500)                                                 
     D                 DS                                                                           
     D  OPT                    1      5                                                             
     D                                     DIM(5)                                                   
     D  OPT001                 1      1                                                             
     D  OPT002                 2      2                                                             
     D  OPT003                 3      3                                                             
     D  OPT004                 4      4                                                             
     D  OPT005                 5      5                                                             
     D                 DS                                                                           
     D  CDR                    1     50                                                             
     D                                     DIM(5)                                                   
     D  CDR001                 1     10                                                             
     D  CDR002                11     20                                                             
     D  CDR003                21     30                                                             
     D  CDR004                31     40                                                             
     D  CDR005                41     50                                                             
     D                 DS                                                                           
     D  NMR                    1    120                                                             
     D                                     DIM(5)                                                   
     D  NMR001                 1     24                                                             
     D  NMR002                25     48                                                             
     D  NMR003                49     72                                                             
     D  NMR004                73     96                                                             
     D  NMR005                97    120                                                             
     C*----------------------------------------------------+                                        
     C     *ENTRY        PLIST                                                  |                   
     C                   PARM                    PRM001           10            |                   
     C*----------------------------------------------------+                                        
     C*( 初期画面 )                                                                                 
     C     *LOVAL        SETLL     SHOHIN                                                           
     C                   EXSR      READ                                                             
     C*----------------------------------------------------+                                        
     C     START         TAG                                                    |                   
     C                   EXFMT     WINDOW                                       |                   
     C*----------------------------------------------------+                                        
     C                   SETOFF                                       99                            
     C*( CF12 )- 前画面                                                                             
     C     *IN12         IFEQ      '1'                                          CF12                
     C                   SETON                                        LR                            
     C   LR              RETURN                                                                     
     C                   END                                                    CF12                
     C*( ROLL-UP)                                                                                   
     C     *IN14         IFEQ      '1'                                          ROLLUP              
     C                   EXSR      ROLLUP                                                           
     C                   END                                                    ROLLUP              
     C*( ROLL-DOWN )                                                                                
     C     *IN15         IFEQ      '1'                                          ROLDWN              
     C                   EXSR      ROLDWN                                                           
     C                   END                                                    ROLDWN              
     C*( CHECK )                                                                                    
     C                   EXSR      CHECK                                                            
     C                   GOTO      START                                                            
     C******************************************************                                        
     C     *INZSR        BEGSR                                                                      
     C******************************************************                                        
     C*  初期のみの実行                                                                             
     CSR                 Z-ADD     8             WNDL                                               
     CSR                 Z-ADD     29            WNDP                                               
     CSR                 MOVE      *LOVAL        SETCOD           10                                
     CSR                 Z-ADD     1             RL                4 0                              
     CSR                 MOVE      *BLANKS       PRM001                                             
     CSR   INZEND        ENDSR                                                                      
     C******************************************************                                        
     C     READ          BEGSR                                                                      
     C******************************************************                                        
     CSR                 EXSR      CLEAR                                                            
     CSR   1             DO        5             N                 4 0          N=1-5               
     CSR                 READ      SHOHIN                                 50                        
     CSR 50              GOTO      REDEND                                                           
     CSR   N             IFEQ      1                                            =1                  
     CSR                 MOVE      SHCODE        KYR(RL)                                            
     CSR                 END                                                    =1                  
     CSR                 MOVE      SHCODE        CDR(N)                                             
     CSR                 MOVE      SHNAME        NMR(N)                                             
     CSR                 END                                                    N=1-5               
     CSR   REDEND        ENDSR                                                                      
     C******************************************************                                        
     C     CLEAR         BEGSR                                                                      
     C******************************************************                                        
     CSR                 MOVE      *BLANKS       OPT                                                
     CSR                 MOVE      *BLANKS       CDR                                                
     CSR                 MOVE      *BLANKS       NMR                                                
     CSR                 ENDSR                                                                      
     C******************************************************                                        
     C     ROLLUP        BEGSR                                                                      
     C******************************************************                                        
     CSR                 ADD       1             RL                                                 
     CSR                 EXSR      READ                                                             
     CSR                 ENDSR                                                                      
     C******************************************************                                        
     C     ROLDWN        BEGSR                                                                      
     C******************************************************                                        
     CSR   RL            IFGT      1                                            >1                  
     CSR                 SUB       1             RL                                                 
     CSR   KYR(RL)       SETLL     SHOHIN                                                           
     CSR                 EXSR      READ                                                             
     CSR                 END                                                    >1                  
     CSR                 ENDSR                                                                      
     C******************************************************                                        
     C     CHECK         BEGSR                                                                      
     C******************************************************                                        
     CSR   1             DO        5             N                                                  
     CSR   OPT(N)        IFEQ      '1'                                          =1                  
     CSR                 MOVE      CDR(N)        PRM001                                             
     CSR                 SETON                                        LR                            
     CSR                 RETURN                                                                     
     CSR                 END                                                    =1                  
     CSR                 END                                                                        
     CSR                 ENDSR