H            Y/                                                      SNDFTP
     F********** FTP によるファイル送信 *******************************         
     FQFTPSRC O   F     240            DISK                                     
     F*****************************************************************         
     E                    CAR    26  26  1                                      
     E                    CBR    26  26  1                                      
     E                    SRC       228  1                                      
     ISRCDTA      DS                                                            
     I                                        1 228 SRC                         
     I              'LTYPE C 932'         C         LTYPE                       
    +C*----------------------------------------------------+                    
     C*    受取りパラメーター                              |                    
     C*----------------------------------------------------+                    
     C           *ENTRY    PLIST                           |                    
     C                     PARM           USER   13        |                    
     C                     PARM           PASS   13        |                    
     C                     PARM           FILE   10        |                    
     C                     PARM           FILLIB 10        |                    
     C                     PARM           MBR    10        |                    
     C                     PARM           TOPASS128        |                    
     C                     PARM           OPT     3        |                    
     C*----------------------------------------------------+                    
     C*( USER & PASSWORD  を CCSID=5035 モードに変更して送信 )                  
     C                     MOVE *BLANKS   SRCDTA                                
     C           USER      CAT  PASS:1    SRCDTA                                
     C                     EXSR CONVRT                                          
     C                     EXSR OUTPUT                                          
     C                     MOVELLTYPE     SRCDTA                                
     C                     EXSR OUTPUT                                          
     C*( TOPASS : DIR 名も CCSID=5035 モードに変更 )                            
     C                     MOVELTOPASS    SRCDTA                                
     C                     EXSR CONVRT                                          
     C                     MOVELSRCDTA    TOPASS                                
     C                     MOVE *BLANKS   SRCDTA                                
     C*( 転送記述 )                                                             
     C           OPT       IFEQ 'PUT'                                           
     C           OPT       CAT  FILLIB:1  SRCDTA                                
     C           SRCDTA    CAT  '/':0     SRCDTA                                
     C           SRCDTA    CAT  FILE:0    SRCDTA                                
     C           SRCDTA    CAT  '.':0     SRCDTA                                
     C           SRCDTA    CAT  MBR:0     SRCDTA                                
     C           SRCDTA    CAT  TOPASS:1  SRCDTA                                
     C                     ELSE                                                 
     C           OPT       CAT  TOPASS:1  SRCDTA                                
     C           SRCDTA    CAT  FILLIB:1  SRCDTA                                
     C           SRCDTA    CAT  '/':0     SRCDTA                                
     C           SRCDTA    CAT  FILE:0    SRCDTA                                
     C           SRCDTA    CAT  '.':0     SRCDTA                                
     C           SRCDTA    CAT  MBR:0     SRCDTA                                
     C                     END                                                  
     C                     EXSR OUTPUT                                          
     C*                                                                         
     C                     MOVEL'CLOSE'   SRCDTA                                
     C                     EXSR OUTPUT                                          
     C                     MOVEL'QUIT'    SRCDTA                                
     C                     EXSR OUTPUT                                          
     C                     SETON                     LR                         
     C******************************************************                    
     C           CONVRT    BEGSR                                                
     C******************************************************                    
     CSR         1         DO   228       N       40                            
     CSR                   MOVE SRC,N     FLD1    1                             
     CSR                   Z-ADD1         M       40                            
     CSR         FLD1      LOKUPCAR,M                    50                     
     CSR 50                MOVE CBR,M     FLD1                                  
     CSR 50                MOVE FLD1      SRC,N                                 
     CSR                   END                                                  
     CSR                   ENDSR                                                
     C******************************************************                    
     C           OUTPUT    BEGSR                                                
     C******************************************************                    
     CSR                   ADD  1         SRCNO   62                            
     CSR                   MOVE UDATE     SRCDAT  6                             
     C*----------------------------------------------------+                    
     C                     EXCPT@ADD                       |                    
     C*----------------------------------------------------+                    
     CSR                   MOVE *BLANKS   SRCDTA                                
     CSR                   ENDSR                                                
     OQFTPSRC E                @ADD                                             
     O                         SRCNO      6                                     
     O                         SRCDAT    12                                     
     O                         SRCDTA   240                                     
** CAR                                                                          
ｱｲｳｴｵｶｷｸｹﾀﾁﾂﾃﾄﾅﾆﾇﾈﾍﾎﾏﾐﾓﾒﾓﾔ                                                      
** CBR                                                                          
abcdefghijklmnopqrstuvwxyz