H        1   Y/                                                      SQL001
     F********** SQL 印刷サンプル：品種別商品一覧表  ******************         
     FQPRINT  O   F     132     OF    LPRINTER                                  
     F*****************************************************************         
     E                    HDR     1   1 32                見出し                
     E                    DAR         2 10                                      
     LQPRINT   66FL 62OL                                                        
     I*( データ・ベース外部データ構造 )                                         
     IFMT001    E DSSHOHIN                                                      
     IFMT002    E DSHINSHU                                                      
     C******************************************************                    
     C*    SQL 文のカーソルの前準備                                             
     C******************************************************                    
     C* SELECT 文によってカーソル C1 を用意                                     
     C/EXEC SQL DECLARE C1 CURSOR FOR                                           
     C+  SELECT T1.SHCODE, T1.SHNAME, T1.SHTANK, T1.SHSCOD,                     
     C+         T2.HNSNAM FROM QTRFIL/SHOHIN T1, QTRFIL/HINSHU T2               
     C+         WHERE T1.SHSCOD = T2.HNSCOD                                     
     C+         ORDER BY T1.SHSCOD, T1.SHCODE                                   
     C/END-EXEC                                                                 
     C*  カーソルをオープン                                                     
     C/EXEC SQL                                                                 
     C+   OPEN C1                                                               
     C/END-EXEC                                                                 
     C******************************************************                    
     C*            明　　細　　演　　算                                         
     C******************************************************                    
     C           *LIKE     DEFN SHSCOD    SHSCOB                                
     C                     MOVE *LOVAL    SHSCOB                                
     C/EXEC SQL WHENEVER NOT FOUND GOTO EOF                                     
     C/END-EXEC                                                                 
     C                     DO   *HIVAL                                          
     C/EXEC SQL                                                                 
     C+   FETCH C1 INTO :SHCODE, :SHNAME, :SHTANK, :SHSCOD,                     
     C+                 :HNSNAM                                                 
     C/END-EXEC                                                                 
     C*( 明細印刷 )                                                             
     C           SHSCOB    COMP SHSCOD                   40                     
     C*----------------------------------------------------+                    
     C                     SETON                     42    |                    
     C                     EXSR OUTPUT                     | 明細印刷           
     C*----------------------------------------------------+                    
     C                     MOVE SHSCOD    SHSCOB                                
     C                     ADD  1         KENSU   70        件数                
     C                     END                                                  
     C           EOF       TAG                                                  
     C*  カーソルをクローズ                                                     
     C/EXEC SQL                                                                 
     C+  CLOSE C1                                                               
     C/END-EXEC                                                                 
     C           END       TAG                                                  
     C*( T-LR 最終合計 )                                                        
     C*----------------------------------------------------+                    
     C                     SETON                     49    |                    
     C                     EXSR OUTPUT                     | 件数印刷           
     C*----------------------------------------------------+                    
     C                     SETON                     LR                         
     C******************************************************                    
     C           *INZSR    BEGSR                                                
     C******************************************************                    
     C*  初期のみの実行                                                         
     CSR                   CLEARFMT001                                          
     CSR                   CLEARFMT002                                          
     CSR         INZEND    ENDSR                                                
     C******************************************************                    
     C           OUTPUT    BEGSR                                                
     C******************************************************                    
     CSRN40                SETON                     4041                       
     CSR                   EXCPT                                                
     CSR OF                SETOF                     40OF                       
     CSR                   SETOF                     414243                     
     CSR                   SETOF                     444546                     
     CSR                   SETOF                     474849                     
     CSR                   ENDSR                                                
     OQPRINT  E  206   41                                                       
     O                         UDATE Y    8                                     
     O                                   14 ' 作成 '                            
     O                         HDR,1     82                                     
     O                                  128 'PAGE.'                             
     O                         PAGE  Z  131                                     
     O        E  1     41                                                       
     O                                   12 ' 品種コード '                      
     O                         SHSCOD    16                                     
     O                                   24 ' 品種名 '                          
     O                         HNSNAM    38                                     
     O        E  1     41                                                       
     O                                   12 ' 商品コード '                      
     O                                   34 ' 商品名 '                          
     O                                   68 ' 単価 '                            
     O        E  2     42                                                       
     O                         SHCODE    11                                     
     O                         SHNAME    46                                     
     O                         SHTANKJ   70                                     
     O        E  1     49                                                       
     O                                   40 ' 処理件数 '                        
     O                                   57 '. . . . . . . . .'                 
     O                         KENSU 2   65                                     
**  HDR                                                                         
 品種別商品一覧表