A*%%TS  SD  20210805  150710  QTR         REL-V6R1M0  5761-WDS             
     A*%%EC                                                                     
     A                                      DSPSIZ(24 80 *DS3)                  
     A                                      MSGLOC(24)                          
     A                                      PRINT                               
     A*******************************************************************       
     A          R DSPDTA01                                                      
     A*******************************************************************       
     A*%%TS  SD  20210805  150710  QTR         REL-V6R1M0  5761-WDS             
     A                                      TEXT(' 明細画面 01')                
     A                                      CF03(03 ' 終了 ')                   
     A                                      CF05(05 ' 撮影 ')                   
     A                                      CF07(07 ' 画像 ')                   
     A                                      CF10(10 ' 更新 ')                   
     A                                      CF23(23 ' 削除 ')                   
     A                                      CF12(12 ' 前画面 ')                 
     A                                      ROLLUP(07)                          
     A                                      ROLLDOWN(08)                        
     A                                      SETOF(99)                           
     A                                      BLINK                               
     A                                  1  2HTML('TEMPLATE=/AS400-NET.USR/TEMPL-
     A                                      ATE/QTROBJ/CAMERA/CAMERAD.HTM')     
     A                                  1 21' 部品検収の入力 '                  
     A                                      DSPATR(HI)                          
     A            DSPMSG         6A  O  1 53TEXT(' 保守モード ')                
     A                                      DSPATR(HI)                          
     A                                  2 40' 検収日 '                          
     A            BKDATE         8Y 0O  2 49EDTCDE(W)                           
     A                                  3  2' 部品コード '                      
     A            BKNCOD        12A  O  3 17TEXT(' 部品コード ')                
     A                                  4  2' 部品名 '                          
     A            BHNAME        20O  O  4 17TEXT(' 部品名 ')                    
     A                                  5  2' 検収数 '                          
     A            BKNUKO         7Y 0B  5 17TEXT(' 検収数 ')                    
     A                                      EDTCDE(K)                           
     A                                  6  2' 摘要 '                            
     A            BKTEKI        21G  B  6 17TEXT(' 摘要 UNICODE *EMOJI')        
     A                                      DSPATR(PC)                          
     A                                      CCSID(1200 21)                      
     A*                                 6 61'( 絵文字入力可 )'                  
     A                                  8  2' ↓ボタンを押して検収品を撮影して +
     A                                       ください。 '                       
     A                                      COLOR(BLU)                          
     A                                  9  2' 写真 '                            
     A            BPHOTO       504A  B  9 17TEXT(' 写真 =42 桁 * 12 行表示 *IMA-
     A                                      GE')                                
     A                                      CNTFLD(042)                         
     A*                                                                         
     A            F3FLD          2Y 0B 23  2PSHBTNFLD(*RSTCSR (*NUMCOL 1))      
     A                                      TEXT(' 終了ボタン ')                
     A                                      PSHBTNCHC(1 '*END' CF03)            
     A            CAMERA         2Y 0B 23 10PSHBTNFLD(*RSTCSR (*NUMCOL 1))      
     A                                      TEXT(' カメラ撮影 ')                
     A                                      PSHBTNCHC(1 '*CAMERA' CF05)         
     A            PICTURE        2Y 0B 23 21PSHBTNFLD(*RSTCSR (*NUMCOL 1))      
     A                                      TEXT(' 画像の検索 ')                
     A                                      PSHBTNCHC(1 '*PICTURE' CF07)        
     A            UPLOAD         2Y 0B 23 34PSHBTNFLD(*RSTCSR (*NUMCOL 1))      
     A                                      TEXT(' アップロードキー ')          
     A                                      PSHBTNCHC(1 '*UPLOAD' CF09)         
     A            UPDATE         2Y 0B 23 47PSHBTNFLD(*RSTCSR (*NUMCOL 1))      
     A                                      TEXT(' 更新キー ')                  
     A                                      PSHBTNCHC(1 '*UPDATE' CF10)         
     A            PREV           2Y 0B 23 60PSHBTNFLD(*RSTCSR (*NUMCOL 1))      
     A                                      TEXT(' 戻る ')                      
     A                                      PSHBTNCHC(1 '*PREV' CF12)           
     A                                 22  2'                                  -
     A                                                             '            
     A                                      DSPATR(UL)                          
      *******************************************************************       
     A          R DSPHEAD                                                       
      *******************************************************************       
     A                                      TEXT(' 初期画面 ')                  
     A*            11:59:33    QSECOFR     REL-R06M00  5714-UT1                 
     A                                      CF03(03 ' 終了 ')                   
     A                                      ROLLUP(07)                          
     A                                      ROLLDOWN(08)                        
     A                                      BLINK                               
     A                                  1 21' 部品検収の入力 '                  
     A                                      DSPATR(HI)                          
     A                                  2 40' 検収日 '                          
     A            BKDATE         8Y 0B  2 49                                    
     A                                      EDTCDE(W)                           
     A                                  3  2' 部品コード '                      
     A            BKNCOD        12A  B  3 17TEXT(' 部品コード ')                
     A                                 11 13' 部品コードを入れて +              
     A                                       実行キーを押してください '         
     A                                      DSPATR(HI)                          
     A            F3FLD          2Y 0B 23  2PSHBTNFLD(*RSTCSR (*NUMCOL 1))      
     A                                      TEXT(' 終了ボタン ')                
     A                                      PSHBTNCHC(1 '*END' CF03)            
      *******************************************************************       
     A          R ENDOPT                                                        
      *******************************************************************       
     A                                      TEXT(' 終了画面 ')                  
     A                                      CF03(03 ' 終了 ')                   
     A                                      CSRLOC(LIN        POS)              
     A                                  1 34' 終了 '                            
     A                                      COLOR(PNK)                          
     A                                      DSPATR(HI)                          
     A                                  3  2' 処理されたレコード数 '            
     A                                  5 10' 追加  . . . . . :'                
     A            ADDREC         5Y 0O  5 35EDTCDE(4)                           
     A                                  6 10' 変更  . . . . . :'                
     A            CHGREC         5Y 0O  6 35EDTCDE(4)                           
     A                                  7 10' 削除  . . . . . :'                
     A            DLTREC         5Y 0O  7 35EDTCDE(4)                           
     A                                 11  2' 選択項目を打鍵して，実行キーを押 +
     A                                       してください。 '                   
     A                                      COLOR(BLU)                          
     A                                 13  5' データ入力の終了  . . . . . .'    
     A            ANS            1A  B 13 39VALUES('Y' 'N')                     
     A                                 13 53'Y=YES, N=NO'                       
     A            F3FLD          2Y 0B 23  2PSHBTNFLD(*RSTCSR (*NUMCOL 1))      
     A                                      TEXT(' 終了ボタン ')                
     A                                      PSHBTNCHC(1 '*END' CF03)            
     A            PREV           2Y 0B 23 15PSHBTNFLD(*RSTCSR (*NUMCOL 1))      
     A                                      TEXT(' 戻る ')                      
     A                                      PSHBTNCHC(1 '*PREV' CF12)           
     A            LIN            3S 0H                                          
     A            POS            3S 0H